### TEMPLATE OPE FILE FOR nuMOIRCS 
### Version-20241108 -- simplified v1!
<HEADER>
PROPOSALID=O240000
OBSERVATION_PERIOD=2024-01-01-18:00:00 - 2024-01-02-06:00:00
</HEADER>
<PARAMETER_LIST>
######################################################################
###     OBJECT LIST     ##############################################
######################################################################
#>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#>>> To Users: Put the coordinate of your targets here.
#>>> *** Use CAPITAL ONLY. ***
#>>> The format is 'RA=HHMMSS.SSS DEC=DDMMSS.SS'.
#>>> See the MOIRCS HP for the definition of the PA.
#
# Words after 'OBJECT=' will be in the fits header. The use of letters, 
#  numbers, and '_' is highly recommended for header. But if you need to 
#  use spaces, '-', or lower case, enclose the phrase in double quotation.
#>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

### MAIN TARGET ##
# For MOS mask target...put the center coordinate of the mask.
# For Longslit with marker star...put the coordinate of the star (not obj).

ARP220F1=OBJECT=ARP220 RA=153457.100 DEC=233511.00 EQUINOX=2000.0 PA=0.0
M83=OBJECT="MESSIER 83" RA=133700.900 DEC=-295156.00 EQUINOX=2000.0 PA=0.0


### TELLURIC STANDARD STARS for spec. ##
# >>> To Users: 
# Fill Here. "Usually" an A0V star from HIP catalog is used.
# for R500 --> r'= 8-9 mag. / For medium resolution --> 7-8 mag recommended
# Add its crude R magnitude at the end of the target definition.

HIP101748=OBJECT=HIP101748 RA=203720.13 DEC=+352610.2 EQUINOX=2000.0 PA=90.0 MAG=9


### SPECTROPHOTOMETRIC STANDARDS: 
# >>> To Users: Usually not necessary.
##  To SA/IO: use CALSPEC_NIR_20230502.ope in the MOIRCS/ direcotry.
P330E=OBJECT=P330E RA=163133.60 DEC=300848.0 EQUINOX=2000.0 PA=0.0 MAG=12.5


###  FOCUSING TARGETS ##
##  To SA/IO: use MOIRCS_FocusingFields.ope in the MOIRCS/ direcotry.
##  Usually SA FILLS THE PART. USERS DO NOT NEED TO FILL IN.

M53=OBJECT=M53 RA=131255.300 DEC=+181009.00 EQUINOX=2000.0 PA=0.0


######################################################################
###   GROBAL SETTINGS (Do Not Change Below) ##########################
######################################################################
###
### LOADING MOIRCS TURRET SETTINGS ###
# >> For the complete list of the currently defined settings, 
#   see the website below.
# http://subarutelescope.org/Observing/Instruments/MOIRCS/FilterSetting_all.htm

*LOAD "moircs_mec2024.prm"

# example of definition:
# DEF_LS_J_J=FILTER1=J FILTER2=CSLM FILTER3=LS_J

######################################################################
### Description of available longslit masks can be found below.
# https://docs.google.com/presentation/d/1DIyBLcTbJjsLC8VozCLUVT9o4b9X_fOhDq1Ml4DBH3g/edit?usp=drive_link
######################################################################

### OFFSET FOR MCSLS_R500_1 -- CHIP-1 SLIT POSITION (UPDATED June 2016) 
OFF_LSR500_1_UHOLE=DX=-64.278 DY=55.136
OFF_LSR500_1_DHOLE=DX=-64.278 DY=-56.384

# Locating a obj at the center of ch2 window: for CHIPJUMP.sk
LS_CH2WIN_C=DX=110.0 DY=0

### OFFSET FOR MCSLS_VPH2 --updated 20200131--
# MCSLS_VPH2 mask: center hole of each slit position: see manual
OFF_LSVPH_S1=SLITX=1763 SLITY=336 SLITCHIP=1
OFF_LSVPH_S2=SLITX=1405 SLITY=1563 SLITCHIP=1
OFF_LSVPH_S3=SLITX=1057 SLITY=651 SLITCHIP=1
OFF_LSVPH_S4=SLITX=712 SLITY=1257 SLITCHIP=1
OFF_LSVPH_S5=SLITX=365 SLITY=953 SLITCHIP=1

### OFFSET FOR LS200905NEW2 -- CHIP-2 SLIT POSITION (UPDATED Jun 2018)
## 0.8, UHOLE, 0.5, 1.1 (46" length each), DHOLE,0.3, 2.0 (23" length)
LS0905WIN_UHOLE=SLITX=840 SLITY=1535 SLITCHIP=2
LS0905WIN_DHOLE=SLITX=835 SLITY=603 SLITCHIP=2
LS0905WIN_CENTER=SLITX=1185 SLITY=1019 SLITCHIP=2

### OFFSET FOR LS200905NEW2 -- CHIP1 WINDOW SIDE (UPDATED 2020-01-31)
# It will bring star to the window closer to the target hole/hole
LS0905WIN_H0.8=SLITX=1100 SLITY=1771 SLITCHIP=1
LS0905WIN_UHOLE=SLITX=1100 SLITY=1517 SLITCHIP=1
LS0905WIN_H0.5=SLITX=1100 SLITY=1265 SLITCHIP=1
LS0905WIN_H1.1=SLITX=1100 SLITY=829 SLITCHIP=1
LS0905WIN_DHOLE=SLITX=1100 SLITY=577 SLITCHIP=1
LS0905WIN_H0.3=SLITX=1100 SLITY=434 SLITCHIP=1
LS0905WIN_H2.0=SLITX=1100 SLITY=211 SLITCHIP=1

### OFFSET FOR LS200709 chip2 (MEASURED BY 2007-11-16 DATA!!OLD!!)
## 0.5, 0.8, 1.1 has 400pix length. / 0.3 and 2.0 has 200 pix.
# Offset for chip-jump = 136".
LS0709_2_0.3=SLITX=824 SLITY=1880 SLITCHIP=2
LS0709_2_2.0=SLITX=824 SLITY=1660 SLITCHIP=2
LS0709_2_UHOLE=SLITX=824 SLITY=1517 SLITCHIP=2
LS0709_2_0.8=SLITX=824 SLITY=1240 SLITCHIP=2
LS0709_2_1.1=SLITX=821 SLITY=825 SLITCHIP=2
LS0709_2_DHOLE=SLITX=819 SLITY=564 SLITCHIP=2
LS0709_2_0.5=SLITX=817 SLITY=290 SLITCHIP=2
LS0709_1_0.3=SLITX=1181 SLITY=1927 SLITCHIP=1
LS0709_1_2.0=SLITX=1176 SLITY=1695 SLITCHIP=1
LS0709_1_UHOLE=SLITX=1172 SLITY=1553 SLITCHIP=1
LS0709_1_0.8=SLITX=1169 SLITY=1290 SLITCHIP=1
LS0709_1_1.1=SLITX=1162 SLITY=846 SLITCHIP=1
LS0709_1_DHOLE=SLITX=1159 SLITY=596 SLITCHIP=1
LS0709_1_0.5=SLITX=1157 SLITY=330 SLITCHIP=1

######################################################################
### OFFSET VALUE FOR SLITS FOR STD ON USER MASKS
# OFF_(MaskName)_(channel)
#>>> To Users: WORK WITH SA to fill below.
#>> SLITX and SLITY are x and y coordinates (raw image) of
#>> the slit to be used for the standard star observation.

OFF_USERMASK1_1=SLITX=1730 SLITY=646 SLITCHIP=1
OFF_USERMASK1_2=SLITX=351 SLITY=1859 SLITCHIP=2

#>> DX and DY case: offset for target slit from pointing center.
#>>  pointing center: ch1=(1826,990), ch2=(217,1017) # 2023-05-25
# OFF_USERMASK1_1=DX=-0 DY=0
# OFF_USERMASK1_2=DX=+0 DY=0

</PARAMETER_LIST>

<COMMAND>
###############################################################
########### CALIBRATION PART ##################################
###############################################################
### PRECHECK -- also available in Launcher ###
#>>> For OPERATORS -- Execute with Cell Cover CLOSED.
#>>> To SA/OP: check items are below.
#        - Is the image not of MOS mask?
#        - No condensation? No AG/Calprobe Shadow?
#        - Count should be around 9000+-3000 ADU.
#        - ch2/ch1 count ratio should be ~1.1 around the center.

CHECKFIELD       $DEF_IMG $DEF_IMKS OBJECT=PRECHECK EXPTIME=5.0
#   PUT BP AFTER PRECHECK!
SETUPOBE         $DEF_IMG $DEF_DARK

###########################
### DARK ##################
###########################
#>>> To Users: Darks are usually not important.
#>>    However you can take some darks to sample bad pixels
#>>    for Dome Flats (especially useful for spec dome and 
#>>    Arc-Lamp data).

SETUPOBE         $DEF_IMG $DEF_DARK

# take below if you have time (just for health check)...
GETOBJECT        $DEF_IMG OBJECT=DARK EXPTIME=3 NDR=1 NEXPOSURE=10 DATTYPE=DARK


####################################################
### CALIBRATION DATA ACQUISITION SEQUENCE -- spec ##
####################################################
# The whole sequence takes ~10-15 min.
## Optional CELLCOVER CLOSE command -- avoid the strong light on detectors!
# Note that SETUPOBE command also has the cover open/close function.

CELLCOVER $DEF_TOOL POSITION=CLOSE

## (1) ASK CREW TO TURN-ON DOME LAMP --> CONFIRM.
#<<< Lamp Setting is below -- use 600W -- for new dome flat panel>>>
# ZJ500  0.8"  60V 3.3sec  18500ADU
# HK500  0.8"  60V 2.5sec  17500ADU
# LS_J   0.7" 120V 8.0sec 180000ADU
# LS_H   0.7" 120V 6.0sec 170000ADU
# VB_K   0.8" 120V 5.0sec 170000ADU

# FOR the 2nd or Later sequence 
#    --> Change voltage appropriately by Launcher while the process (2).

## (2) LOAD MOS MASK ###
# >> To Users: Ask the SA for the names of your MOS mask frames.
## SLOT  SLIT_NAME
#  0  M83_MOS1
#  1  ARP220F1_PA1
# 13  MCSLS_R500_1
# 14  LS200905NEW2
# 15  LS200709NEW
# 16  MCSLS_LONG
# 17  MCSLS_VPH2

SETUPOBE         $DEF_MOS EXCHANGE_MODE=START MASK=M83_MOS1 ZENITH=NO
SETUPOBE         $DEF_MOS EXCHANGE_MODE=EXCHANGE MASK=ARP220F1_PA1 ZENITH=NO


## (3) FILTER CHANGE
# To Users: Fill the grism settings you use here.
# See -> https://subarutelescope.org/Observing/Instruments/MOIRCS/FilterSetting_all.htm
# e.g. HK500+OC_HK setting...
SETUPOBE         $DEF_MOS $DEF_HK500

## (4) OPEN CELLCOVER --> CONFIRM.
CELLCOVER $DEF_TOOL POSITION=OPEN


## (5) COUNT CHECK
CHECKFIELD       $DEF_MOS OBJECT=TEST EXPTIME=2 QDAS_FRAME=1

## (6)  LAMP-ON DATA ACQUISITION
GETOBJECT        $DEF_MOS OBJECT=DOMEFLAT EXPTIME=3 NEXPOSURE=7 DATTYPE=DOMEFLAT

## (7) ASK THE TelOp TO SET "Voltage=0" of the DOME LAMP --> CONFIRM.
# If you don't use the lamp any more, you can shutdown dome flat lamp.
# SetupDomeflat OBE_ID=COMMON OBE_MODE=TOOL Setup=CHANGE Lamp=4X600W Volt=0


## (8) HK500/VB_K: LAMP-OFF DOME DATA ACQUISITION
## For ZJ500/VPHY/LS_J/H No need --> Take Dark data with the SAME EXPOSURE as 
##    the lamp-on dome instead.
GETOBJECT        $DEF_MOS OBJECT=DOMEFLAT_OFF EXPTIME=3 NEXPOSURE=7 DATTYPE=DOMEFLAT

## (9) CLOSING CELLCOVER --> CONFIRM. 
## If you have next mask for dome flat, ask the Lamp setup for next MOS anytime below.

CELLCOVER $DEF_TOOL POSITION=CLOSE

## (10) ASK TelOp TO SETUP "Th-Ar" CAL LAMP (HCT2, r=-30) --> CONFIRM.
# SETTING: zJ500 -> w IRND1, 3 sec/ VPH-Y -> w IRND1 5-8 sec
#          LS_J -> w IRND1, 5 sec / LS_H -> w IRND1, 1.5 sec
#          HK500 -> w IRND1, 3-5 sec (Use GETCALFLAT_K)
#          VB_K -> w IRND1, 7-10 sec (Use GETCALFLAT_K)

## (11) Th-Ar DATA ACQUISITION
# for countcheck:
GETCALFLAT       $DEF_TOOL OBJECT="TH-AR" EXPTIME=3 STEP=[-30] DATTYPE=TEST

# actual obs
GETCALFLAT       $DEF_TOOL OBJECT="TH-AR" EXPTIME=5 NEXPOSURE=1 STEP=[-60 -20 20 60] 

# **K-band case** Use GETCALFLAT_K. It automatically turns-on HCT lamp at each position. *** No need to manually turn-on HCT lamp! ***
# GETCALFLAT_K       $DEF_TOOL OBJECT="TH-AR" EXPTIME=5 NEXPOSURE=1 STEP=[-60 -20 20 60] LAMPON=YES

# Darks with the same exposure time as ThAr may help...take optionally later.

## (12) Turn-OFF CAL, ASK Operator to RETRACT CAL Probe --> CONFIRM.

## (13) FILTER CHANGE FOR MASK IMAGE
SETUPOBE         $DEF_MOS $DEF_IMMBK4

## (14) MASK IMAGE ACQUISITION
GETOBJECT        $DEF_MOS OBJECT=MASKIMAGE EXPTIME=3 NEXPOSURE=1 DATTYPE=DOMEFLAT

## END! For next mask, go back to (1) and repeat the sequence.


##################################
### STORE MASK  ##################
SETUPOBE         $DEF_MOS EXCHANGE_MODE=FIN ZENITH=NO 


###############################################################
########### OBSERVATION PART ##################################
###############################################################

###########################
### FOCUSING ##############
###########################
#### USUAL FOCUSING BY A CLUSTER ####
SETUPFIELD       $DEF_IMG $M53 $DEF_IMBRG
# Change Z value to appropriate one.
FOCUSTELESCOPE   $DEF_TOOL EXPTIME=5.0 NSTEP=7 Z=0.05 DELTAZ=0.03 FOCUS_MODE=FITSVIEW


#### SINGLE-STAR FOCUSING CASE ####
## CASE1: SETUPFIELD with DX=107.5 -> Locating a star at the center of the channel 2.
SETUPFIELD       $DEF_IMG $P330E DX=107.5 DY=0
CHECKFIELD       $DEF_IMG EXPTIME=2
FOCUSTELESCOPE   $DEF_TOOL EXPTIME=2.0 NSTEP=7 Z=-0.05 DELTAZ=0.05 FOCUS_MODE=SINGLE FOCUS_AREA=2

## CASE 2: QDAS USE -- Move a high-SN star to the FOV center. 
# !! Change INPUT_FRAME and FOCUS_AREA according to the chip used.
# Take Checkfield data first!
CHECKFIELD       $DEF_IMG EXPTIME=2
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK2 
FOCUSTELESCOPE   $DEF_TOOL EXPTIME=2.0 NSTEP=7 Z=-0.05 DELTAZ=0.05 FOCUS_MODE=SINGLE FOCUS_AREA=2



# BKUP
# TELOFFSET        $DEF_TOOL DX=107.5 DY=0 AUTOGUIDE=NO

######################################################
### SPEC: MOS ACQUISITION TARGET1  ###################
######################################################
#   TARGET ACQUISITION
# >>> To Users: please change the target alias (and filter as necessary). 

SETUPFIELD       $DEF_MOS $M83 $DEF_IMKS AUTOGUIDE=NO

#   FOV CHECK
CHECKFIELD       $DEF_MOS EXPTIME=10 SKYSUB=YES QDAS_FRAME=2

##  SETUPSLIT -- TARGET ACQUISITION TO MOS MASK
# >>> To Users: Ask SA for the name of your masks. Change below to your mask name.>>>
#  0  M83_MOS1

SETUPSLIT        $DEF_MOS EXCHANGE_MODE=START MASK=M83_MOS1 EXPTIME=15 ZENITH=YES

#   FOR FURTHER ITERATION -- "ANA WINDOW" FOR OFFSET
CHECKFIELD       $DEF_MOS EXPTIME=15 QDAS_FRAME=2 SKYSUB=NO
TELOFFSET        $DEF_TOOL MODE=ANA PROBESYNC=NO


### ALIGN COMPLETE -->  SPEC DATA ACQUISITION    ###
### >>> To Users:  CHANGE GRISM DEFINITION, EXPTME, and DITHLENGTH etc.

GETOBJECT        $DEF_MOS $DEF_HK500 EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.5
GETOBJECT        $DEF_MOS EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.4
GETOBJECT        $DEF_MOS EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.6
GETOBJECT        $DEF_MOS $DEF_HK500 EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.5
GETOBJECT        $DEF_MOS EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.4
GETOBJECT        $DEF_MOS EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.6
GETOBJECT        $DEF_MOS EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.5
## (repeat for 1 - 1.5 hrs, then move to "MOS STAR CHECK" below.)



############################################
##    BACKUP: TROUBLE RECOVERY          ####

# !! This assume Telescope is at Zenith!! IF NOT, don't use below.

# 1. Solve MOS trouble first! [Comerr? Lost Status?? UPD by MacroLog]
#    Then, complete mask set up.
SETUPOBE         $DEF_MOS EXCHANGE_MODE=START MASK=M83_MOS1 ZENITH=NO

# 2. Take a mask image.
CHECKFIELD       $DEF_MOS EXPTIME=15 QDAS_FRAME=2 SKYSUB=NO

# 3. Run the same SETUPFIELD again.

# 4. Execute the mesoffset0 process, then measure Dx and Dy. 
# 5. Run the command below. Input the DxDy to fits view window.
TELOFFSET        $DEF_TOOL MODE=ANA

# 6. Take a mask+star image.
CHECKFIELD       $DEF_MOS EXPTIME=15 QDAS_FRAME=2 SKYSUB=NO
# 7. After confirming that the star is in the holes, *** Exec DoAG from launcher ***
# DOAG OBE_ID=MOIRCS OBE_MODE=LAUNCHER AG_Select=Manual EXPTIME_FACTOR=1.0 READREGION=200 CALCREGION=180

# 8. Continue mesoffset0 process...move to "FOR FURTHER ITERATION" (fine tuning) part afterwards.

##backup
# SETUPOBE         $DEF_MOS $DEF_IMJ
# TELOFFSET        $DEF_TOOL MODE=OBS DX=0.0 DY=0.0 AUTOGUIDE=NO
# PAOFFSET $DEF_TOOL DPA=360 AUTOGUIDE=NO
##########


###########################################
### MOS STAR CHECK          ###############
###########################################

## 1. QUICK RE-ALIGNMENT by "QDAS": use a bright alignment star 
#    If the final alignment is good, you can use the method.
# !! Change INPUT_FRAME !!

CHECKFIELD       $DEF_MOS  $DEF_IMKS EXPTIME=15.0 QDAS_FRAME=1 SKYSUB=NO
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1 PROBESYNC=NO

### IF OK, BACK TO GETOBJECT COMMANDS ###


## 2. FOR "MESOFFSET MODE=FINE" method.
# Use below if alignment stars are too faint, or when alignment err is large.
CHECKFIELD       $DEF_MOS EXPTIME=15.0 QDAS_FRAME=1 SKYSUB=YES SKYAGOFF=YES
CHECKFIELD       $DEF_MOS EXPTIME=15.0 QDAS_FRAME=1 SKYSUB=NO
TELOFFSET        $DEF_TOOL MODE=ANA PROBESYNC=NO


#########################################################################
### STORE MASK (FIN): Automatically goes to AZ=80, then stop.  ##########
# Do not forget Turning OFF the AG 

SETUPOBE         $DEF_MOS EXCHANGE_MODE=FIN ZENITH=YES BACKPOS=NO
# SETUPOBE         $DEF_MOS EXCHANGE_MODE=STORE ZENITH=YES BACKPOS=NO
#########################################################################


#########################################################################
### SPEC. STANDARD STAR ACQUISITION ON MOS                        #######
#########################################################################

### 1. AGsetupfield method...star acquisition witout removing mask.
# >>> To Users: please change the target alias name here. 
# If the target slit is on chip 1/2 -> INPUT_FRAME=CHECK1/2
# Pointing center on detector: ch1=(1826,990), ch2=(217,1017) #2023-05-25

AGSETUPFIELD       $DEF_MOS $DEF_IMH2 $HIP101748 INPUT_FRAME=CHECK1 EXPTIME=2.0
#   Further Tuning BY QDAS
CHECKFIELD       $DEF_SPEC EXPTIME=2.0 QDAS_FRAME=1
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1 PROBESYNC=NO

#  Align complete? --> Go to "GRISM SELECT AND EXPOSURE" Part.

### 2. Normal SETUPFIELD case...use this if the STD obs starts before MOS.

SETUPFIELD       $DEF_MOS $DEF_IMH2 $HIP101748 $OFF_USERMASK1_1 AUTOGUIDE=NO
CHECKFIELD       $DEF_MOS EXPTIME=2 SKYSUB=NO QDAS_FRAME=1
#   Correct position as necessary
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1 AUTOGUIDE=NO

#  SETUPSLIT -- Using QDAS WINDOW in DEF_SPEC mode
#>>> To Users: Ask SA for the name of your mask. Change below to your masks.>>>
#  0  M83_MOS1
#  1  ARP220_PA1
SETUPSLIT        $DEF_SPEC EXCHANGE_MODE=START MASK=M83_MOS1 QDAS_FRAME=1 EXPTIME=5 ZENITH=YES

#  further tuning...BY QDAS
CHECKFIELD       $DEF_SPEC EXPTIME=5 SKYSUB=NO QDAS_FRAME=1
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1 PROBESYNC=NO

#  Align complete? --> Go to "GRISM SELECT AND EXPOSURE" Part.


# BKUP: with Sky Subtraction: INPUT_FRAME=[current_frame Sky_Frame]
# TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=[MCSA00245678 MCSA00245680] PROBESYNC=NO


#######  GRISM SELECT AND EXPOSURE  #####
#   COUNTCHECK   
CHECKFIELD       $DEF_SPEC $DEF_HK500 EXPTIME=2 QDAS_FRAME=1

##   DATA ACQUISITION
# >>> To Users: set the grism name you use here.
GETOBJECT        $DEF_SPEC $DEF_HK500 EXPTIME=4 DITHNUM=2 DITHLENGTH=5.0 DATTYPE=STANDARD_STAR
GETOBJECT        $DEF_SPEC $DEF_HK500 EXPTIME=4 DITHNUM=2 DITHLENGTH=5.2 DATTYPE=STANDARD_STAR

### !! REMOVE MOS MASK after the STD obs as necessary !! ###

#########################################################################
### STORE MASK: Automatically goes to AZ=80, then stops.   
SETUPOBE         $DEF_MOS EXCHANGE_MODE=FIN ZENITH=YES AUTOGUIDE=NO BACKPOS=NO
#########################################################################



#########################################################
### SPEC: FAINT OBJ ACQUISITION by a LONGSLIT MASK  #####
#########################################################
###
### 1. Regular Alignment 
###
# >> USER: please change the target alias name here. 
SETUPFIELD       $DEF_SPEC $DEF_IMKS $M83 $OFF_LSR500_1_UHOLE 

#   FieldCheck, identify target.
CHECKFIELD       $DEF_MOS EXPTIME=15 AUTOGUIDE=NO QDAS_FRAME=1 SKYSUB=YES

##   Correction by QDAS + RAW data as needed...
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1
# if sky subtraction on QDAS is needed, use below after changing file name
TELOFFSET        $DEF_TOOL MODE=QDAS OBJECTFRAME=MCSA00234565 SKYFRAME=MCSA00234567

##  SETUPSLIT -- Using QDAS WINDOW in DEF_SPEC mode
# >>> If target is faint and need the sky data, change $DEF_SPEC to $DEF_MOS.
#   13 MCSLS_R500_1
#   14 LS200905NEW2
#   15 LS200709NEW
#   16 MCSLS_LONG
#   17 MCSLS_VPH2
SETUPSLIT        $DEF_SPEC EXCHANGE_MODE=START MASK=MCSLS_R500_1 QDAS_FRAME=1 EXPTIME=15 ZENITH=YES SKYSUB=NO

## FURTHER TUNING...by QDAS+ RAW data
CHECKFIELD       $DEF_SPEC EXPTIME=15 QDAS_FRAME=1
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1 PROBESYNC=NO
# with Sky Subtraction: INPUT_FRAME=[current_frame Sky_Frame]
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=[MCSA00045397 MCSA00045401] PROBESYNC=YES

## Align complete? --> Go to "DEEP EXPOSURE" Part.

###
### 2. Chip-Jump Alignment: Use when the Longslit Mask is already on the focal plane
###    Use a marker star [J<19, Ks<18, separation <~60"] for alignment.

# locate the marker star to the center of ch2 window.
SETUPFIELD       $DEF_SPEC $DEF_IMJ $ARP220F1 $LS_CH2WIN_C AUTOGUIDE=NO

#   FieldCheck, confirm marker star.
CHECKFIELD       $DEF_SPEC EXPTIME=15 QDAS_FRAME=2 SKYSUB=YES
# If necessary, correct the position (optional).
#TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK2

# Chip Jump!! Move the star from ch2 window to ch1 alignment box.
# follow the message on IntegGUI2.
CHIPJUMP $DEF_TOOL STARTCHIP=2 EXPTIME=15

# !! Start AG !! ** Exec DoAG from launcher (or below). ***
DOAG OBE_ID=MOIRCS OBE_MODE=LAUNCHER AG_Select=Manual READREGION=200 CALCREGION=180 AGCENTER=YES

#  Perform FINE Alignent with AG
CHECKFIELD       $DEF_MOS EXPTIME=10 QDAS_FRAME=1 SKYSUB=NO
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1 PROBESYNC=NO

## Align complete? --> Go to "DEEP EXPOSURE" Part.

#BKUP: if sky subtraction on QDAS is needed...
#TELOFFSET        $DEF_TOOL MODE=QDAS OBJECTFRAME=MCSA00234565 SKYFRAME=MCSA00234567 AUTOGUIDE=NO
# regular offset
# TELOFFSET        $DEF_TOOL DX=0.0 DY=0.0 AUTOGUIDE=NO MODE=OBS



###
###   DEEP  EXPOSURE -- with NDR ###
###
# >>> To Users: Change grism, exposure, and dithlength as you like.
GETOBJECT        $DEF_SPEC $DEF_HK500 EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.5
GETOBJECT        $DEF_SPEC EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.4
GETOBJECT        $DEF_SPEC EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.6
GETOBJECT        $DEF_SPEC $DEF_HK500 EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.5
GETOBJECT        $DEF_SPEC EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.4
GETOBJECT        $DEF_SPEC EXPTIME=180 NDR=10 DITHNUM=2 DITHLENGTH=2.6

## (repeat for 1 - 1.5 hrs, then check the alignment.)


### for STANDARD STAR obs case..  #####
#   countcheck first!
CHECKFIELD       $DEF_SPEC $DEF_HK500 EXPTIME=2 QDAS_FRAME=1
#   data acquisition
# >>> To Users: set the grism name you use here.
GETOBJECT        $DEF_SPEC $DEF_HK500 EXPTIME=4 DITHNUM=2 DITHLENGTH=5.0 DATTYPE=STANDARD_STAR
GETOBJECT        $DEF_SPEC $DEF_HK500 EXPTIME=4 DITHNUM=2 DITHLENGTH=5.2 DATTYPE=STANDARD_STAR




###
### ALIGNMENT CHECK...a case with QDAS+ RAW data
###
CHECKFIELD       $DEF_SPEC $DEF_IMKS EXPTIME=15 QDAS_FRAME=1
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=CHECK1 PROBESYNC=NO

# BKUP: a case with Sky Subtraction: INPUT_FRAME=[current_frame Sky_Frame]
CHECKFIELD       $DEF_SPEC $DEF_IMKS EXPTIME=15 QDAS_FRAME=1 SKYSUB=YES SKYAGOFF=YES
TELOFFSET        $DEF_TOOL MODE=QDAS INPUT_FRAME=[MCSA00045401 MCSA00045403] PROBESYNC=NO


### BKUP: DEEP with SKYNODDING OBS [O-S-O/O-S-O/O-S-O]
#  At the skyposition AG will be turned off.
#GETOBJECT        $DEF_SPEC EXPTIME=240 NDR=10 NEXPOSURE=1 DITHNUM=2 DITHLENGTH=1. SKYNOD=YES NODOFFSET_RA=0 NODOFFSET_DEC=120.0 AUTOGUIDE=YES
#GETOBJECT        $DEF_SPEC EXPTIME=240 NDR=10 NEXPOSURE=1 DITHNUM=2 DITHLENGTH=1.2 SKYNOD=YES NODOFFSET_RA=0 NODOFFSET_DEC=110.0 AUTOGUIDE=YES
#GETOBJECT        $DEF_SPEC EXPTIME=240 NDR=10 NEXPOSURE=1 DITHNUM=2 DITHLENGTH=1.4 SKYNOD=YES NODOFFSET_RA=0 NODOFFSET_DEC=130.0 AUTOGUIDE=YES

###
### STORE MASK when necessary:  Automatically goes to AZ=80, then stops.  #####
### Stop AG first.
SETUPOBE         $DEF_MOS EXCHANGE_MODE=FIN ZENITH=YES BACKPOS=NO

</COMMAND>